Descubre la Programación : Muestra

/**
 * Este programa simula las ondas que se producen en
 * el agua. Cada vez que se pulsa el ratón se genera
 * una onda a partir de esa posición que se va haciendo
 * cada vez más grande y más difusa. Cuando tiene 256
 * puntos de diámetro desaparece. Pueden haber hasta
 * 256 ondas distintas en cada momento. Para conseguir
 * el efecto de difusión se utiliza el parámetro alpha
 * de los colores.
 **/
final int N = 256; // Número de círculos cuya posición se recuerda
int x[] = null; // Coordenada x de los círculos
int y[] = null; // Coordenada y de los círculos
int radio[] = null; // Radio de cada círculo
int n = 0;

void dibuja() {
  noFill();
  for ( int i = 0 ; i < N ; i++ ) {
    // Sólo se dibujan los círculos con radio positivo
    if (radio[i] != -1) {
      // Se hacen más transparentes cuanto más grandes
      stroke(255,255,255, 256-radio[i]);
      ellipse(x[i], y[i], radio[i], radio[i]);
      // Cada vez que se dibuja se hace más grande
      radio[i]++;
      if (radio[i] > 640) {
        radio[i] = -1;
      }
    }
  }
}

void draw() {
  background(0);
  // Si se pulsa el ratón se crea un nuevo círculo
  if (mousePressed) {
    x[n] = mouseX;
    y[n] = mouseY;
    radio[n] = 0;
    n = (n+1)%N;
  }
  dibuja();
}

void main() {
  x = new int[N];
  y = new int[N];
  radio = new int[N];
  // Inicialmente no se pintará ningún círculo
  for ( int i = 0 ; i < N ; i++ ) {
    radio[i] = -1;
  }
  n = 0;
  animate(draw);
}

Programado por jlaguna

51 votos 3022 descargas 2345 usos